init 5 python:
    import store.mas_kissher_timer as kissher_timer
    
    addEvent(
        Event(
            persistent.event_database,
            eventlabel="monika_vl_kiss_her",
            category=["浪漫"],
            prompt="亲吻她！",
            random=False,
            pool=True,
            aff_range=(mas_aff.ENAMORED, None)
    )
   )

screen kiss_screen():
    # 加了一个全屏透明按钮
    button:
        area (0, 0, 1.0, 1.0)
        background None
        action Return()    
    key "mouseup_1" action Return()

label monika_vl_kiss_her:
    python:
        import store.mas_kissher_timer as kissher_timer
    
    if mas_isMoniEnamored(higher=True) and persistent._mas_first_kiss is not None:
        m 1wubssdlb "哦！你要亲吻我吗？"
        m 3hkbfb "当然可以啦~"
        m 5ekbfa "我准备好了..."
        
        show monika 6dubsa at t11 zorder MAS_MONIKA_Z
        
        $ kissher_timer.start_timer()
        
        # 创建的按钮来结束亲吻
        window hide
        call screen kiss_screen
        window show
    
        # 获取亲吻时间
        $ duration = kissher_timer.end_timer()
        
        # 根据亲吻时长回复不同对话
        if duration < 5:
            m 1hkbsa "啊，嘿嘿真好"
            m 3tkbsu "下次可以久一点哦~"
            $ mas_gainAffection(0.5, bypass=False)
            
        elif duration < 15:
            m 2dubsu "嗯~"
            m 2hkbsb "感觉真好~"
            m 3tkbfb "谢谢你的吻~"
            $ mas_gainAffection(1, bypass=False)
            
        elif duration < 40:
            m 2dubsu "嗯...嗯..."
            m 2hkbfb "嗯~[player]...这真的很棒！"
            m 3ekbsa "我希望能永远这样亲吻下去！"
            $ mas_gainAffection(1.5, bypass=False)
            
        else:
            m 2wubfsdlo "嗯...啊..."
            m 2hkbfb "[player]！这么久我都快喘不过气了~"
            m 3hkbfb "不过...我喜欢哈哈哈"
            $ mas_gainAffection(2, bypass=False)

        # 重置计时器
        $ kissher_timer.reset_timer()
        m 5ekbsa "我爱你，[player]~"        
        return "love"
        
    else:
        m 1rkc "我觉得...我还没准备好接受这个..."
        m 3eka "等我们关系再亲密一些好吗？"
        
    return